Re: Displaying Index Markers in Print

["Thomas Michanek" <thomas.michanek@xxxxxxxxx>]

*** The original message appeared on the FrameUsers list.
*** This reply is posted only to the framers@omsys.com mailing list.

From: <Camille_Trentacoste@prenhall.com>
> My Goal: [to present] a hard copy of the formatted pages that will:
> - Display the index markers in place in the text 
>  (it would be OK if it also displayed other text symbols)
> or, most ideally,
> - Display ON PAPER the contents of the markers at their insertion point
>   (even if some of the text is obscured)

This latter request can be fulfilled by using the IXgen utility and
its "Expand Marker" command.
Unfortunately, IXgen is not available for Macintosh (Camille's platform).
For those interested in Linux/UNIX, here's a UNIX solution that works
without having access to IXgen:

Save your FM file to MIF, run the following "ex" command on the MIF file,
and then print the MIF file. The script replaces the index markers with
the text contained in the marker, formatted by using the character tag
MarkerText, which must already be defined in the file (the tag name can
of course can be replaced by any other tag name).

ex - file.mif <<"EOT"
g/<MType 2>/\
?<Marker?,/<MText /-c\
MARKER\
.
g/^MARKER/\
+2,/> # end of Marker/d
g/^MARKER/\
+1 s/<MText/<String/
g/^MARKER/\
+1 a\
<Font <FTag `'> >\
.
g/^MARKER/\
c\
<Font <FTag `MarkerText'> >\
.
w!
q
"EOT"

Not exactly pretty, but surprisingly simple if you know MIF and ex :-)
Anyway, there's the Expand Marker function via MIF. Note that the
the index markers are replaced, so the action cannot be reversed.




** To unsubscribe, send a message to majordomo@omsys.com **
** with "unsubscribe framers" (no quotes) in the body.   **